initial commit

Signed-off-by: Peter Siegmund <mars3142@noreply.mars3142.dev>

libs/wxWidgets-3.3.1/build/cmake/modules/FindCairo.cmake

@@ -0,0 +1,83 @@
+# - Try to find Cairo
+# Once done, this will define
+#
+#  CAIRO_FOUND - system has Cairo
+#  CAIRO_INCLUDE_DIRS - the Cairo include directories
+#  CAIRO_LIBRARIES - link these to use Cairo
+#
+# Copyright (C) 2012 Raphael Kubo da Costa <rakuco@webkit.org>
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1.  Redistributions of source code must retain the above copyright
+#     notice, this list of conditions and the following disclaimer.
+# 2.  Redistributions in binary form must reproduce the above copyright
+#     notice, this list of conditions and the following disclaimer in the
+#     documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDER AND ITS CONTRIBUTORS ``AS
+# IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR ITS
+# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+FIND_PACKAGE(PkgConfig)
+PKG_CHECK_MODULES(PC_CAIRO QUIET cairo)
+
+FIND_PATH(CAIRO_INCLUDE_DIRS
+    NAMES cairo.h
+    HINTS ${PC_CAIRO_INCLUDEDIR}
+          ${PC_CAIRO_INCLUDE_DIRS}
+    PATH_SUFFIXES cairo
+)
+
+FIND_LIBRARY(CAIRO_LIBRARIES
+    NAMES cairo
+    HINTS ${PC_CAIRO_LIBDIR}
+          ${PC_CAIRO_LIBRARY_DIRS}
+)
+
+IF (CAIRO_INCLUDE_DIRS)
+    IF (EXISTS "${CAIRO_INCLUDE_DIRS}/cairo-version.h")
+        FILE(READ "${CAIRO_INCLUDE_DIRS}/cairo-version.h" CAIRO_VERSION_CONTENT)
+
+        STRING(REGEX MATCH "#define +CAIRO_VERSION_MAJOR +([0-9]+)" _dummy "${CAIRO_VERSION_CONTENT}")
+        SET(CAIRO_VERSION_MAJOR "${CMAKE_MATCH_1}")
+
+        STRING(REGEX MATCH "#define +CAIRO_VERSION_MINOR +([0-9]+)" _dummy "${CAIRO_VERSION_CONTENT}")
+        SET(CAIRO_VERSION_MINOR "${CMAKE_MATCH_1}")
+
+        STRING(REGEX MATCH "#define +CAIRO_VERSION_MICRO +([0-9]+)" _dummy "${CAIRO_VERSION_CONTENT}")
+        SET(CAIRO_VERSION_MICRO "${CMAKE_MATCH_1}")
+
+        SET(CAIRO_VERSION "${CAIRO_VERSION_MAJOR}.${CAIRO_VERSION_MINOR}.${CAIRO_VERSION_MICRO}")
+    ENDIF ()
+ENDIF ()
+
+# FIXME: Should not be needed anymore once we start depending on CMake 2.8.3
+SET(VERSION_OK TRUE)
+IF (Cairo_FIND_VERSION)
+    IF (Cairo_FIND_VERSION_EXACT)
+        IF ("${Cairo_FIND_VERSION}" VERSION_EQUAL "${CAIRO_VERSION}")
+            # FIXME: Use IF (NOT ...) with CMake 2.8.2+ to get rid of the ELSE block
+        ELSE ()
+            SET(VERSION_OK FALSE)
+        ENDIF ()
+    ELSE ()
+        IF ("${Cairo_FIND_VERSION}" VERSION_GREATER "${CAIRO_VERSION}")
+            SET(VERSION_OK FALSE)
+        ENDIF ()
+    ENDIF ()
+ENDIF ()
+
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(Cairo DEFAULT_MSG CAIRO_INCLUDE_DIRS CAIRO_LIBRARIES VERSION_OK)
+
+mark_as_advanced(CAIRO_INCLUDE_DIRS CAIRO_LIBRARIES)

libs/wxWidgets-3.3.1/build/cmake/modules/FindFONTCONFIG.cmake

@@ -0,0 +1,30 @@
+# - Try to find Fontconfig
+# Once done this will define
+#
+#  FONTCONFIG_FOUND - system has Fontconfig
+#  FONTCONFIG_INCLUDE_DIRS - The include directory to use for the Fontconfig headers
+#  FONTCONFIG_LIBRARIES - Link these to use Fontconfig
+
+find_package(PkgConfig)
+pkg_check_modules(PC_FONTCONFIG QUIET fontconfig)
+
+find_path(FONTCONFIG_INCLUDE_DIRS
+    NAMES fontconfig.h
+    HINTS ${PC_FONTCONFIG_INCLUDEDIR}
+          ${PC_FONTCONFIG_INCLUDE_DIRS}
+    PATH_SUFFIXES fontconfig
+)
+
+find_library(FONTCONFIG_LIBRARIES
+    NAMES fontconfig
+    HINTS ${PC_FONTCONFIG_LIBDIR}
+          ${PC_FONTCONFIG_LIBRARY_DIRS}
+)
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(FONTCONFIG DEFAULT_MSG FONTCONFIG_INCLUDE_DIRS FONTCONFIG_LIBRARIES)
+
+mark_as_advanced(
+    FONTCONFIG_INCLUDE_DIRS
+    FONTCONFIG_LIBRARIES
+)

libs/wxWidgets-3.3.1/build/cmake/modules/FindGNOMEVFS2.cmake

@@ -0,0 +1,89 @@
+# - Try to find GnomeVFS2
+# Once done this will define
+#
+#  GNOMEVFS2_FOUND - system has GnomeVFS2
+#  GNOMEVFS2_INCLUDE_DIRS - the GnomeVFS2 include directory
+#  GNOMEVFS2_LIBRARIES - Link these to use GnomeVFS2
+#  GNOMEVFS2_DEFINITIONS - Compiler switches required for using GnomeVFS2
+#
+#  Copyright (c) 2008 Joshua L. Blocher <verbalshadow@gmail.com>
+#
+#  Redistribution and use is allowed according to the terms of the New
+#  BSD license.
+#  For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+#
+
+
+if (GNOMEVFS2_LIBRARIES AND GNOMEVFS2_INCLUDE_DIRS)
+  # in cache already
+  set(GNOMEVFS2_FOUND TRUE)
+else (GNOMEVFS2_LIBRARIES AND GNOMEVFS2_INCLUDE_DIRS)
+  # use pkg-config to get the directories and then use these values
+  # in the FIND_PATH() and FIND_LIBRARY() calls
+  if (${CMAKE_MAJOR_VERSION} EQUAL 2 AND ${CMAKE_MINOR_VERSION} EQUAL 4)
+    include(UsePkgConfig)
+    pkgconfig(gnome-vfs-2.0 _GNOMEVFS2_INCLUDEDIR _GNOMEVFS2_LIBDIR _GNOMEVFS2_LDFLAGS _GNOMEVFS2_CFLAGS)
+  else (${CMAKE_MAJOR_VERSION} EQUAL 2 AND ${CMAKE_MINOR_VERSION} EQUAL 4)
+    find_package(PkgConfig)
+    if (PKG_CONFIG_FOUND)
+      pkg_check_modules(_GNOMEVFS2 gnome-vfs-2.0)
+    endif (PKG_CONFIG_FOUND)
+  endif (${CMAKE_MAJOR_VERSION} EQUAL 2 AND ${CMAKE_MINOR_VERSION} EQUAL 4)
+  find_path(GNOMEVFS2_INCLUDE_DIR
+    NAMES
+      libgnomevfs/gnome-vfs.h
+    PATHS
+      ${_GNOMEVFS2_INCLUDEDIR}
+      /usr/include
+      /usr/local/include
+      /opt/local/include
+      /sw/include
+      $ENV{DEVLIBS_PATH}//include//
+    PATH_SUFFIXES
+      gnome-vfs-2.0
+  )
+
+  find_library(GNOMEVFS-2_LIBRARY
+    NAMES
+      gnomevfs-2
+    PATHS
+      ${_GNOMEVFS2_LIBDIR}
+      /usr/lib
+      /usr/local/lib
+      /opt/local/lib
+      /sw/lib
+  )
+
+  if (GNOMEVFS-2_LIBRARY)
+    set(GNOMEVFS-2_FOUND TRUE)
+  endif (GNOMEVFS-2_LIBRARY)
+
+  set(GNOMEVFS2_INCLUDE_DIRS
+    ${GNOMEVFS2_INCLUDE_DIR}
+  )
+
+  if (GNOMEVFS-2_FOUND)
+    set(GNOMEVFS2_LIBRARIES
+      ${GNOMEVFS2_LIBRARIES}
+      ${GNOMEVFS-2_LIBRARY}
+    )
+  endif (GNOMEVFS-2_FOUND)
+
+  if (GNOMEVFS2_INCLUDE_DIRS AND GNOMEVFS2_LIBRARIES)
+     set(GNOMEVFS2_FOUND TRUE)
+  endif (GNOMEVFS2_INCLUDE_DIRS AND GNOMEVFS2_LIBRARIES)
+
+  if (GNOMEVFS2_FOUND)
+    if (NOT GNOMEVFS2_FIND_QUIETLY)
+      message(STATUS "Found GnomeVFS2: ${GNOMEVFS2_LIBRARIES}")
+    endif (NOT GNOMEVFS2_FIND_QUIETLY)
+  else (GNOMEVFS2_FOUND)
+    if (GNOMEVFS2_FIND_REQUIRED)
+      message(FATAL_ERROR "Could not find GnomeVFS2")
+    endif (GNOMEVFS2_FIND_REQUIRED)
+  endif (GNOMEVFS2_FOUND)
+
+  # show the GNOMEVFS2_INCLUDE_DIRS and GNOMEVFS2_LIBRARIES variables only in the advanced view
+  mark_as_advanced(GNOMEVFS2_INCLUDE_DIRS GNOMEVFS2_LIBRARIES GNOMEVFS2_INCLUDE_DIR GNOMEVFS-2_LIBRARY)
+
+endif (GNOMEVFS2_LIBRARIES AND GNOMEVFS2_INCLUDE_DIRS)

libs/wxWidgets-3.3.1/build/cmake/modules/FindGSPELL.cmake

@@ -0,0 +1,42 @@
+# - Try to find gspell
+# Once done this will define
+#
+#  GSPELL_FOUND - system has gspell
+#  GSPELL_INCLUDE_DIRS - The include directory to use for the gspell headers
+#  GSPELL_LIBRARIES - Link these to use gspell
+
+find_package(PkgConfig)
+pkg_check_modules(PC_GSPELL QUIET gspell-1)
+
+find_path(GSPELL_INCLUDE_DIRS
+    NAMES gspell/gspell.h
+    HINTS ${PC_GSPELL_INCLUDEDIR}
+          ${PC_GSPELL_INCLUDE_DIRS}
+)
+
+find_library(GSPELL_LIBRARIES
+    NAMES gspell-1
+    HINTS ${PC_GSPELL_LIBDIR}
+          ${PC_GSPELL_LIBRARY_DIRS}
+)
+
+pkg_check_modules(PC_ENCHANT QUIET enchant-2 enchant)
+find_path(ENCHANT_INCLUDE_DIRS
+    NAMES enchant.h
+    HINTS ${PC_ENCHANT_INCLUDEDIR}
+          ${PC_ENCHANT_INCLUDE_DIRS}
+    PATH_SUFFIXES enchant-2 enchant
+)
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(GSPELL DEFAULT_MSG GSPELL_INCLUDE_DIRS ENCHANT_INCLUDE_DIRS GSPELL_LIBRARIES)
+
+if(GSPELL_FOUND)
+    set(GSPELL_INCLUDE_DIRS ${GSPELL_INCLUDE_DIRS} ${ENCHANT_INCLUDE_DIRS})
+endif()
+
+mark_as_advanced(
+    GSPELL_INCLUDE_DIRS
+    GSPELL_LIBRARIES
+    ENCHANT_INCLUDE_DIRS
+)

libs/wxWidgets-3.3.1/build/cmake/modules/FindGSTREAMER.cmake

@@ -0,0 +1,131 @@
+# - Try to find GStreamer and its plugins
+# Once done, this will define
+#
+#  GSTREAMER_FOUND - system has GStreamer
+#  GSTREAMER_INCLUDE_DIRS - the GStreamer include directories
+#  GSTREAMER_LIBRARIES - link these to use GStreamer
+#
+# Additionally, gstreamer-base is always looked for and required, and
+# the following related variables are defined:
+#
+#  GSTREAMER_BASE_INCLUDE_DIRS - gstreamer-base's include directory
+#  GSTREAMER_BASE_LIBRARIES - link to these to use gstreamer-base
+#
+# Optionally, the COMPONENTS keyword can be passed to find_package()
+# and GStreamer plugins can be looked for.  Currently, the following
+# plugins can be searched, and they define the following variables if
+# found:
+#
+#  gstreamer-app:        GSTREAMER_APP_INCLUDE_DIRS and GSTREAMER_APP_LIBRARIES
+#  gstreamer-audio:      GSTREAMER_AUDIO_INCLUDE_DIRS and GSTREAMER_AUDIO_LIBRARIES
+#  gstreamer-fft:        GSTREAMER_FFT_INCLUDE_DIRS and GSTREAMER_FFT_LIBRARIES
+#  gstreamer-interfaces: GSTREAMER_INTERFACES_INCLUDE_DIRS and GSTREAMER_INTERFACES_LIBRARIES
+#  gstreamer-pbutils:    GSTREAMER_PBUTILS_INCLUDE_DIRS and GSTREAMER_PBUTILS_LIBRARIES
+#  gstreamer-video:      GSTREAMER_VIDEO_INCLUDE_DIRS and GSTREAMER_VIDEO_LIBRARIES
+#  gstreamer-player:     GSTREAMER_PLAYER_INCLUDE_DIRS and GSTREAMER_PLAYER_LIBRARIES
+#
+# Copyright (C) 2012 Raphael Kubo da Costa <rakuco@webkit.org>
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1.  Redistributions of source code must retain the above copyright
+#     notice, this list of conditions and the following disclaimer.
+# 2.  Redistributions in binary form must reproduce the above copyright
+#     notice, this list of conditions and the following disclaimer in the
+#     documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDER AND ITS CONTRIBUTORS ``AS
+# IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR ITS
+# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+find_package(PkgConfig)
+
+# Determine the version in the library name, default is 1.0
+set(GST_LIB_VERSION 1.0)
+if(DEFINED GSTREAMER_FIND_VERSION AND GSTREAMER_FIND_VERSION VERSION_LESS 1.0)
+    set(GST_LIB_VERSION 0.10)
+endif()
+
+# Helper macro to find a GStreamer plugin (or GStreamer itself)
+#   _component_prefix is prepended to the _INCLUDE_DIRS and _LIBRARIES variables (eg. "GSTREAMER_AUDIO")
+#   _pkgconfig_name is the component's pkg-config name (eg. "gstreamer", or "gstreamer-video").
+#   _header is the component's header, relative to the gstreamer-${GST_LIB_VERSION} directory (eg. "gst/gst.h").
+#   _library is the component's library name (eg. "gstreamer" or "gstvideo")
+macro(FIND_GSTREAMER_COMPONENT _component_prefix _pkgconfig_name _header _library)
+    pkg_check_modules(PC_${_component_prefix} QUIET ${_pkgconfig_name}-${GST_LIB_VERSION})
+
+    find_path(${_component_prefix}_INCLUDE_DIRS
+        NAMES ${_header}
+        HINTS ${PC_${_component_prefix}_INCLUDE_DIRS} ${PC_${_component_prefix}_INCLUDEDIR}
+        PATH_SUFFIXES gstreamer-${GST_LIB_VERSION}
+    )
+
+    find_library(${_component_prefix}_LIBRARIES
+        NAMES ${_library}-${GST_LIB_VERSION}
+        HINTS ${PC_${_component_prefix}_LIBRARY_DIRS} ${PC_${_component_prefix}_LIBDIR}
+    )
+
+    mark_as_advanced(${_component_prefix}_INCLUDE_DIRS ${_component_prefix}_LIBRARIES)
+endmacro()
+
+# ------------------------
+# 1. Find GStreamer itself
+# ------------------------
+
+# 1.1. Find headers and libraries
+FIND_GSTREAMER_COMPONENT(GSTREAMER gstreamer gst/gst.h gstreamer)
+FIND_GSTREAMER_COMPONENT(GSTREAMER_BASE gstreamer-base gst/gst.h gstbase)
+
+# 1.2. Check GStreamer version
+if (GSTREAMER_INCLUDE_DIRS)
+    if (EXISTS "${GSTREAMER_INCLUDE_DIRS}/gst/gstversion.h")
+        file(READ "${GSTREAMER_INCLUDE_DIRS}/gst/gstversion.h" GSTREAMER_VERSION_CONTENTS)
+
+        string(REGEX MATCH "#define +GST_VERSION_MAJOR +\\(([0-9]+)\\)" _dummy "${GSTREAMER_VERSION_CONTENTS}")
+        set(GSTREAMER_VERSION_MAJOR "${CMAKE_MATCH_1}")
+
+        string(REGEX MATCH "#define +GST_VERSION_MINOR +\\(([0-9]+)\\)" _dummy "${GSTREAMER_VERSION_CONTENTS}")
+        set(GSTREAMER_VERSION_MINOR "${CMAKE_MATCH_1}")
+
+        string(REGEX MATCH "#define +GST_VERSION_MICRO +\\(([0-9]+)\\)" _dummy "${GSTREAMER_VERSION_CONTENTS}")
+        set(GSTREAMER_VERSION_MICRO "${CMAKE_MATCH_1}")
+
+        set(GSTREAMER_VERSION "${GSTREAMER_VERSION_MAJOR}.${GSTREAMER_VERSION_MINOR}.${GSTREAMER_VERSION_MICRO}")
+    endif ()
+endif ()
+
+# -------------------------
+# 2. Find GStreamer plugins
+# -------------------------
+
+FIND_GSTREAMER_COMPONENT(GSTREAMER_APP gstreamer-app gst/app/gstappsink.h gstapp)
+FIND_GSTREAMER_COMPONENT(GSTREAMER_AUDIO gstreamer-audio gst/audio/audio.h gstaudio)
+FIND_GSTREAMER_COMPONENT(GSTREAMER_FFT gstreamer-fft gst/fft/gstfft.h gstfft)
+FIND_GSTREAMER_COMPONENT(GSTREAMER_INTERFACES gstreamer-interfaces gst/interfaces/mixer.h gstinterfaces)
+FIND_GSTREAMER_COMPONENT(GSTREAMER_PBUTILS gstreamer-pbutils gst/pbutils/pbutils.h gstpbutils)
+FIND_GSTREAMER_COMPONENT(GSTREAMER_VIDEO gstreamer-video gst/video/video.h gstvideo)
+FIND_GSTREAMER_COMPONENT(GSTREAMER_PLAYER gstreamer-player gst/player/player.h gstplayer)
+
+# ------------------------------------------------
+# 3. Process the COMPONENTS passed to FIND_PACKAGE
+# ------------------------------------------------
+set(_GSTREAMER_REQUIRED_VARS GSTREAMER_VERSION GSTREAMER_INCLUDE_DIRS GSTREAMER_LIBRARIES GSTREAMER_BASE_INCLUDE_DIRS GSTREAMER_BASE_LIBRARIES)
+
+foreach (_component ${GSTREAMER_FIND_COMPONENTS})
+    set(_gst_component "GSTREAMER_${_component}")
+    string(TOUPPER ${_gst_component} _UPPER_NAME)
+
+    list(APPEND _GSTREAMER_REQUIRED_VARS ${_UPPER_NAME}_INCLUDE_DIRS ${_UPPER_NAME}_LIBRARIES)
+endforeach ()
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(GSTREAMER DEFAULT_MSG ${_GSTREAMER_REQUIRED_VARS})

libs/wxWidgets-3.3.1/build/cmake/modules/FindGTK3.cmake

@@ -0,0 +1,53 @@
+# - Try to find GTK+ 3
+# Once done, this will define
+#
+# GTK3_FOUND - system has GTK+ 3.
+# GTK3_INCLUDE_DIRS - the GTK+ 3. include directories
+# GTK3_LIBRARIES - link these to use GTK+ 3.
+#
+# Copyright (C) 2012 Raphael Kubo da Costa <rakuco@webkit.org>
+# Copyright (C) 2013 Igalia S.L.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1. Redistributions of source code must retain the above copyright
+# notice, this list of conditions and the following disclaimer.
+# 2. Redistributions in binary form must reproduce the above copyright
+# notice, this list of conditions and the following disclaimer in the
+# documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDER AND ITS CONTRIBUTORS ``AS
+# IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR ITS
+# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+find_package(PkgConfig)
+pkg_check_modules(GTK3 QUIET gtk+-3.0)
+set(VERSION_OK TRUE)
+if (GTK3_VERSION)
+if (GTK3_FIND_VERSION_EXACT)
+if (NOT("${GTK3_FIND_VERSION}" VERSION_EQUAL "${GTK3_VERSION}"))
+set(VERSION_OK FALSE)
+endif ()
+else ()
+if ("${GTK3_VERSION}" VERSION_LESS "${GTK3_FIND_VERSION}")
+set(VERSION_OK FALSE)
+endif ()
+endif ()
+endif ()
+# Check for GDK Wayland support
+include(CheckSymbolExists)
+set(CMAKE_REQUIRED_INCLUDES ${GTK3_INCLUDE_DIRS})
+check_symbol_exists(GDK_WINDOWING_WAYLAND "gdk/gdk.h" wxHAVE_GDK_WAYLAND)
+check_symbol_exists(GDK_WINDOWING_X11 "gdk/gdk.h" wxHAVE_GDK_X11)
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(GTK3 DEFAULT_MSG GTK3_INCLUDE_DIRS GTK3_LIBRARIES VERSION_OK)
+
+mark_as_advanced(GTK3_INCLUDE_DIRS GTK3_LIBRARIES)

libs/wxWidgets-3.3.1/build/cmake/modules/FindGTK4.cmake

@@ -0,0 +1,48 @@
+# - Try to find GTK+ 4
+# Once done, this will define
+#
+# GTK4_FOUND - system has GTK+ 4.
+# GTK4_INCLUDE_DIRS - the GTK+ 4. include directories
+# GTK4_LIBRARIES - link these to use GTK+ 4.
+#
+# Copyright (C) 2012 Raphael Kubo da Costa <rakuco@webkit.org>
+# Copyright (C) 2013 Igalia S.L.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1. Redistributions of source code must retain the above copyright
+# notice, this list of conditions and the following disclaimer.
+# 2. Redistributions in binary form must reproduce the above copyright
+# notice, this list of conditions and the following disclaimer in the
+# documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDER AND ITS CONTRIBUTORS ``AS
+# IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR ITS
+# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+find_package(PkgConfig)
+pkg_check_modules(GTK4 QUIET gtk4)
+set(VERSION_OK TRUE)
+if (GTK4_VERSION)
+if (GTK4_FIND_VERSION_EXACT)
+if (NOT("${GTK4_FIND_VERSION}" VERSION_EQUAL "${GTK4_VERSION}"))
+set(VERSION_OK FALSE)
+endif ()
+else ()
+if ("${GTK4_VERSION}" VERSION_LESS "${GTK4_FIND_VERSION}")
+set(VERSION_OK FALSE)
+endif ()
+endif ()
+endif ()
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(GTK4 DEFAULT_MSG GTK4_INCLUDE_DIRS GTK4_LIBRARIES VERSION_OK)
+
+mark_as_advanced(GTK4_INCLUDE_DIRS GTK4_LIBRARIES)

libs/wxWidgets-3.3.1/build/cmake/modules/FindGTKPRINT.cmake

@@ -0,0 +1,33 @@
+# - Try to find GTK Print
+# Provide the GTK version as argument
+# Once done this will define
+#
+#  GTKPRINT_FOUND - system has GTK Print
+#  GTKPRINT_INCLUDE_DIRS - The include directory to use for the GTK Print headers
+
+if(NOT GTKPRINT_FIND_VERSION EQUAL GTKPRINT_FIND_VERSION_USED)
+    unset(GTKPRINT_FOUND CACHE)
+    unset(GTKPRINT_INCLUDE_DIRS CACHE)
+    unset(GTKPRINT_FIND_VERSION_USED CACHE)
+endif()
+set(GTKPRINT_FIND_VERSION_USED "${GTKPRINT_FIND_VERSION}" CACHE INTERNAL "")
+
+if(GTKPRINT_FIND_VERSION VERSION_LESS 3.0)
+    set(GTKPRINT_LIB_NAME "gtk+-unix-print-2.0")
+else()
+    set(GTKPRINT_LIB_NAME "gtk+-unix-print-3.0")
+endif()
+
+find_package(PkgConfig)
+pkg_check_modules(PC_GTKPRINT QUIET ${GTKPRINT_LIB_NAME})
+
+find_path(GTKPRINT_INCLUDE_DIRS
+    NAMES gtk/gtkunixprint.h
+    HINTS ${PC_GTKPRINT_INCLUDEDIR}
+          ${PC_GTKPRINT_INCLUDE_DIRS}
+)
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(GTKPRINT DEFAULT_MSG GTKPRINT_INCLUDE_DIRS)
+
+mark_as_advanced(GTKPRINT_INCLUDE_DIRS)

libs/wxWidgets-3.3.1/build/cmake/modules/FindICONV.cmake

@@ -0,0 +1,61 @@
+# https://github.com/onyx-intl/cmake_modules/blob/master/FindIconv.cmake
+#
+# - Try to find Iconv
+# Once done this will define
+#
+#  ICONV_FOUND - system has Iconv
+#  ICONV_INCLUDE_DIR - the Iconv include directory
+#  ICONV_LIBRARIES - Link these to use Iconv
+#  ICONV_SECOND_ARGUMENT_IS_CONST - the second argument for iconv() is const
+#
+include(CheckCXXSourceCompiles)
+
+IF (ICONV_INCLUDE_DIR AND ICONV_LIBRARIES)
+  # Already in cache, be silent
+  SET(ICONV_FIND_QUIETLY TRUE)
+ENDIF (ICONV_INCLUDE_DIR AND ICONV_LIBRARIES)
+
+FIND_PATH(ICONV_INCLUDE_DIR iconv.h)
+
+FIND_LIBRARY(ICONV_LIBRARIES NAMES iconv libiconv libiconv-2 c)
+
+IF(ICONV_INCLUDE_DIR AND ICONV_LIBRARIES)
+   SET(ICONV_FOUND TRUE)
+ENDIF(ICONV_INCLUDE_DIR AND ICONV_LIBRARIES)
+
+set(CMAKE_REQUIRED_INCLUDES ${ICONV_INCLUDE_DIR})
+set(CMAKE_REQUIRED_LIBRARIES ${ICONV_LIBRARIES})
+set(CMAKE_REQUIRED_QUIET ON)
+IF(ICONV_FOUND)
+  check_cxx_source_compiles("
+  #include <iconv.h>
+  int main(){
+    iconv_t conv = 0;
+    const char* in = 0;
+    size_t ilen = 0;
+    char* out = 0;
+    size_t olen = 0;
+    iconv(conv, &in, &ilen, &out, &olen);
+    return 0;
+  }
+" ICONV_SECOND_ARGUMENT_IS_CONST )
+ENDIF(ICONV_FOUND)
+set(CMAKE_REQUIRED_INCLUDES)
+set(CMAKE_REQUIRED_LIBRARIES)
+set(CMAKE_REQUIRED_QUIET)
+
+IF(ICONV_FOUND)
+  IF(NOT ICONV_FIND_QUIETLY)
+    MESSAGE(STATUS "Found Iconv: ${ICONV_LIBRARIES}")
+  ENDIF(NOT ICONV_FIND_QUIETLY)
+ELSE(ICONV_FOUND)
+  IF(ICONV_FIND_REQUIRED)
+    MESSAGE(FATAL_ERROR "Could not find Iconv")
+  ENDIF(ICONV_FIND_REQUIRED)
+ENDIF(ICONV_FOUND)
+
+MARK_AS_ADVANCED(
+  ICONV_INCLUDE_DIR
+  ICONV_LIBRARIES
+  ICONV_SECOND_ARGUMENT_IS_CONST
+)

libs/wxWidgets-3.3.1/build/cmake/modules/FindLIBNOTIFY.cmake

@@ -0,0 +1,55 @@
+# - Try to find LibNotify
+# This module defines the following variables:
+#
+#  LIBNOTIFY_FOUND - LibNotify was found
+#  LIBNOTIFY_INCLUDE_DIRS - the LibNotify include directories
+#  LIBNOTIFY_LIBRARIES - link these to use LibNotify
+#
+# Copyright (C) 2012 Raphael Kubo da Costa <rakuco@webkit.org>
+# Copyright (C) 2014 Collabora Ltd.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1.  Redistributions of source code must retain the above copyright
+#     notice, this list of conditions and the following disclaimer.
+# 2.  Redistributions in binary form must reproduce the above copyright
+#     notice, this list of conditions and the following disclaimer in the
+#     documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDER AND ITS CONTRIBUTORS ``AS
+# IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR ITS
+# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+find_package(PkgConfig)
+pkg_check_modules(LIBNOTIFY QUIET libnotify)
+
+find_path(LIBNOTIFY_INCLUDE_DIRS
+    NAMES notify.h
+    HINTS ${LIBNOTIFY_INCLUDEDIR}
+          ${LIBNOTIFY_INCLUDE_DIRS}
+    PATH_SUFFIXES libnotify
+)
+
+find_library(LIBNOTIFY_LIBRARIES
+    NAMES notify
+    HINTS ${LIBNOTIFY_LIBDIR}
+          ${LIBNOTIFY_LIBRARY_DIRS}
+)
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBNOTIFY REQUIRED_VARS LIBNOTIFY_INCLUDE_DIRS LIBNOTIFY_LIBRARIES
+                                            VERSION_VAR   LIBNOTIFY_VERSION)
+
+mark_as_advanced(
+    LIBNOTIFY_INCLUDE_DIRS
+    LIBNOTIFY_LIBRARIES
+)

libs/wxWidgets-3.3.1/build/cmake/modules/FindLIBSECRET.cmake

@@ -0,0 +1,51 @@
+# - Try to find libsecret
+# Once done, this will define
+#
+#  LIBSECRET_FOUND - system has libsecret
+#  LIBSECRET_INCLUDE_DIRS - the libsecret include directories
+#  LIBSECRET_LIBRARIES - link these to use libsecret
+#
+# Copyright (C) 2012 Raphael Kubo da Costa <rakuco@webkit.org>
+# Copyright (C) 2014 Igalia S.L.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1.  Redistributions of source code must retain the above copyright
+#     notice, this list of conditions and the following disclaimer.
+# 2.  Redistributions in binary form must reproduce the above copyright
+#     notice, this list of conditions and the following disclaimer in the
+#     documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDER AND ITS CONTRIBUTORS ``AS
+# IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR ITS
+# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+find_package(PkgConfig)
+pkg_check_modules(LIBSECRET QUIET libsecret-1)
+
+set(VERSION_OK TRUE)
+if (LIBSECRET_VERSION)
+    if (LIBSECRET_FIND_VERSION_EXACT)
+        if (NOT("${LIBSECRET_FIND_VERSION}" VERSION_EQUAL "${LIBSECRET_VERSION}"))
+            set(VERSION_OK FALSE)
+        endif ()
+    else ()
+        if ("${LIBSECRET_VERSION}" VERSION_LESS "${LIBSECRET_FIND_VERSION}")
+            set(VERSION_OK FALSE)
+        endif ()
+    endif ()
+endif ()
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBSECRET DEFAULT_MSG LIBSECRET_INCLUDE_DIRS LIBSECRET_LIBRARIES VERSION_OK)
+
+mark_as_advanced(LIBSECRET_INCLUDE_DIRS LIBSECRET_LIBRARIES)

libs/wxWidgets-3.3.1/build/cmake/modules/FindLIBSOUP.cmake

@@ -0,0 +1,64 @@
+# - Try to find LibSoup 2.4
+# This module defines the following variables:
+#
+#  LIBSOUP_FOUND - LibSoup 2.4 was found
+#  LIBSOUP_INCLUDE_DIRS - the LibSoup 2.4 include directories
+#  LIBSOUP_LIBRARIES - link these to use LibSoup 2.4
+#
+# Copyright (C) 2012 Raphael Kubo da Costa <rakuco@webkit.org>
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1.  Redistributions of source code must retain the above copyright
+#     notice, this list of conditions and the following disclaimer.
+# 2.  Redistributions in binary form must reproduce the above copyright
+#     notice, this list of conditions and the following disclaimer in the
+#     documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDER AND ITS CONTRIBUTORS ``AS
+# IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
+# THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR ITS
+# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
+# EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
+# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
+# OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
+# WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
+# OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
+# ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+# LibSoup does not provide an easy way to retrieve its version other than its
+# .pc file, so we need to rely on PC_LIBSOUP_VERSION and REQUIRE the .pc file
+# to be found.
+SET(LIBSOUP_VERSION 2.4)
+if(DEFINED LIBSOUP_FIND_VERSION)
+    SET(LIBSOUP_VERSION ${LIBSOUP_FIND_VERSION})
+endif()
+
+set(LIBSOUP_INCLUDE_DIRS LIBSOUP_INCLUDE_DIRS-NOTFOUND)
+set(LIBSOUP_LIBRARIES LIBSOUP_LIBRARIES-NOTFOUND)
+
+FIND_PACKAGE(PkgConfig)
+PKG_CHECK_MODULES(PC_LIBSOUP QUIET libsoup-${LIBSOUP_VERSION})
+
+if(PC_LIBSOUP_FOUND)
+    FIND_PATH(LIBSOUP_INCLUDE_DIRS
+        NAMES libsoup/soup.h
+        HINTS ${PC_LIBSOUP_INCLUDEDIR}
+        ${PC_LIBSOUP_INCLUDE_DIRS}
+        PATH_SUFFIXES libsoup-${LIBSOUP_VERSION}
+        )
+
+    FIND_LIBRARY(LIBSOUP_LIBRARIES
+        NAMES soup-${LIBSOUP_VERSION}
+        HINTS ${PC_LIBSOUP_LIBDIR}
+        ${PC_LIBSOUP_LIBRARY_DIRS}
+        )
+endif()
+
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(LIBSOUP REQUIRED_VARS LIBSOUP_INCLUDE_DIRS LIBSOUP_LIBRARIES
+    VERSION_VAR   PC_LIBSOUP_VERSION)
+
+mark_as_advanced(LIBSOUP_LIBRARIES LIBSOUP_INCLUDE_DIRS)

libs/wxWidgets-3.3.1/build/cmake/modules/FindMSPACK.cmake

@@ -0,0 +1,40 @@
+## FindMSPACK.cmake
+##
+## Copyright (C) 2016 Christian Schenk
+## 
+## This file is free software; you can redistribute it and/or modify
+## it under the terms of the GNU General Public License as published
+## by the Free Software Foundation; either version 2, or (at your
+## option) any later version.
+## 
+## This file is distributed in the hope that it will be useful, but
+## WITHOUT ANY WARRANTY; without even the implied warranty of
+## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+## General Public License for more details.
+## 
+## You should have received a copy of the GNU General Public License
+## along with this file; if not, write to the Free Software
+## Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307,
+## USA.
+
+find_path(MSPACK_INCLUDE_DIR
+  NAMES
+    mspack.h
+)
+
+find_library(MSPACK_LIBRARY
+  NAMES
+    mspack
+)
+
+find_package_handle_standard_args(MSPACK DEFAULT_MSG MSPACK_LIBRARY MSPACK_INCLUDE_DIR)
+
+if(MSPACK_FOUND)
+  set(MSPACK_INCLUDE_DIRS ${MSPACK_INCLUDE_DIR})
+  set(MSPACK_LIBRARIES ${MSPACK_LIBRARY})
+else()
+  set(MSPACK_INCLUDE_DIRS)
+  set(MSPACK_LIBRARIES)
+endif()
+
+mark_as_advanced(MSPACK_LIBRARY MSPACK_INCLUDE_DIR)

libs/wxWidgets-3.3.1/build/cmake/modules/FindPANGOFT2.cmake

@@ -0,0 +1,30 @@
+# - Try to find PangoFT2
+# Once done this will define
+#
+#  PANGOFT2_FOUND - system has PangoFT2
+#  PANGOFT2_INCLUDE_DIRS - The include directory to use for the PangoFT2 headers
+#  PANGOFT2_LIBRARIES - Link these to use PangoFT2
+
+find_package(PkgConfig)
+pkg_check_modules(PC_PANGOFT2 QUIET pangoft2)
+
+find_path(PANGOFT2_INCLUDE_DIRS
+    NAMES pango-context.h
+    HINTS ${PC_PANGOFT2_INCLUDEDIR}
+          ${PC_PANGOFT2_INCLUDE_DIRS}
+    PATH_SUFFIXES pango
+)
+
+find_library(PANGOFT2_LIBRARIES
+    NAMES pangoft2-1.0
+    HINTS ${PC_PANGOFT2_LIBDIR}
+          ${PC_PANGOFT2_LIBRARY_DIRS}
+)
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(PANGOFT2 REQUIRED_VARS PANGOFT2_INCLUDE_DIRS PANGOFT2_LIBRARIES)
+
+mark_as_advanced(
+    PANGOFT2_INCLUDE_DIRS
+    PANGOFT2_LIBRARIES
+)

libs/wxWidgets-3.3.1/build/cmake/modules/FindPCRE2.cmake

@@ -0,0 +1,43 @@
+# Find the PCRE2 headers and libraries.
+#
+#  Optionally define the following variables:
+#     PCRE2_CODE_UNIT_WIDTH - code unit width: 8 (default), 16 or 32 bit.
+#
+#  This module defines the following variables:
+#     PCRE2_FOUND        - true if PCRE2 is found.
+#     PCRE2_INCLUDE_DIRS - list of PCRE2 include directories.
+#     PCRE2_LIBRARIES    - list of PCRE2 libraries.
+
+if(NOT PCRE2_CODE_UNIT_WIDTH)
+    set(PCRE2_CODE_UNIT_WIDTH 8)
+endif()
+
+if(NOT PCRE2_CODE_UNIT_WIDTH EQUAL PCRE2_CODE_UNIT_WIDTH_USED)
+    unset(PCRE2_CODE_UNIT_WIDTH_USED CACHE)
+    unset(PCRE2_FOUND CACHE)
+    unset(PCRE2_INCLUDE_DIRS CACHE)
+    unset(PCRE2_LIBRARIES CACHE)
+endif()
+
+set(PCRE2_CODE_UNIT_WIDTH_USED "${PCRE2_CODE_UNIT_WIDTH}" CACHE INTERNAL "")
+
+
+find_package(PkgConfig QUIET)
+pkg_check_modules(PC_PCRE2 QUIET libpcre2-${PCRE2_CODE_UNIT_WIDTH})
+
+find_path(PCRE2_INCLUDE_DIRS
+    NAMES pcre2.h
+    HINTS ${PC_PCRE2_INCLUDEDIR}
+          ${PC_PCRE2_INCLUDE_DIRS}
+)
+
+find_library(PCRE2_LIBRARIES
+    NAMES pcre2-${PCRE2_CODE_UNIT_WIDTH}
+    HINTS ${PC_PCRE2_LIBDIR}
+          ${PC_PCRE2_LIBRARY_DIRS}
+)
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(PCRE2 REQUIRED_VARS PCRE2_LIBRARIES PCRE2_INCLUDE_DIRS VERSION_VAR PC_PCRE2_VERSION)
+
+mark_as_advanced(PCRE2_LIBRARIES PCRE2_INCLUDE_DIRS)

libs/wxWidgets-3.3.1/build/cmake/modules/FindSDL2.cmake

@@ -0,0 +1,175 @@
+
+# This module defines
+# SDL2_LIBRARY, the name of the library to link against
+# SDL2_FOUND, if false, do not try to link to SDL2
+# SDL2_INCLUDE_DIR, where to find SDL.h
+#
+# This module responds to the the flag:
+# SDL2_BUILDING_LIBRARY
+# If this is defined, then no SDL2main will be linked in because
+# only applications need main().
+# Otherwise, it is assumed you are building an application and this
+# module will attempt to locate and set the the proper link flags
+# as part of the returned SDL2_LIBRARY variable.
+#
+# Don't forget to include SDLmain.h and SDLmain.m your project for the
+# OS X framework based version. (Other versions link to -lSDL2main which
+# this module will try to find on your behalf.) Also for OS X, this
+# module will automatically add the -framework Cocoa on your behalf.
+#
+#
+# Additional Note: If you see an empty SDL2_LIBRARY_TEMP in your configuration
+# and no SDL2_LIBRARY, it means CMake did not find your SDL2 library
+# (SDL2.dll, libsdl2.so, SDL2.framework, etc).
+# Set SDL2_LIBRARY_TEMP to point to your SDL2 library, and configure again.
+# Similarly, if you see an empty SDL2MAIN_LIBRARY, you should set this value
+# as appropriate. These values are used to generate the final SDL2_LIBRARY
+# variable, but when these values are unset, SDL2_LIBRARY does not get created.
+#
+#
+# $SDL2DIR is an environment variable that would
+# correspond to the ./configure --prefix=$SDL2DIR
+# used in building SDL2.
+# l.e.galup  9-20-02
+#
+# Modified by Eric Wing.
+# Added code to assist with automated building by using environmental variables
+# and providing a more controlled/consistent search behavior.
+# Added new modifications to recognize OS X frameworks and
+# additional Unix paths (FreeBSD, etc).
+# Also corrected the header search path to follow "proper" SDL guidelines.
+# Added a search for SDL2main which is needed by some platforms.
+# Added a search for threads which is needed by some platforms.
+# Added needed compile switches for MinGW.
+#
+# On OSX, this will prefer the Framework version (if found) over others.
+# People will have to manually change the cache values of
+# SDL2_LIBRARY to override this selection or set the CMake environment
+# CMAKE_INCLUDE_PATH to modify the search paths.
+#
+# Note that the header path has changed from SDL2/SDL.h to just SDL.h
+# This needed to change because "proper" SDL convention
+# is #include "SDL.h", not <SDL2/SDL.h>. This is done for portability
+# reasons because not all systems place things in SDL2/ (see FreeBSD).
+
+#=============================================================================
+# Copyright 2003-2009 Kitware, Inc.
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+# message("<FindSDL2.cmake>")
+
+SET(SDL2_SEARCH_PATHS
+	~/Library/Frameworks
+	/Library/Frameworks
+	/usr/local
+	/usr
+	/sw # Fink
+	/opt/local # DarwinPorts
+	/opt/csw # Blastwave
+	/opt
+	${SDL2_PATH}
+)
+
+FIND_PATH(SDL2_INCLUDE_DIR SDL.h
+	HINTS
+	$ENV{SDL2DIR}
+	PATH_SUFFIXES include/SDL2 include
+	PATHS ${SDL2_SEARCH_PATHS}
+)
+
+if(CMAKE_SIZEOF_VOID_P EQUAL 8)
+	set(PATH_SUFFIXES lib64 lib/x64 lib)
+else()
+	set(PATH_SUFFIXES lib/x86 lib)
+endif()
+
+FIND_LIBRARY(SDL2_LIBRARY_TEMP
+	NAMES SDL2
+	HINTS
+	$ENV{SDL2DIR}
+	PATH_SUFFIXES ${PATH_SUFFIXES}
+	PATHS ${SDL2_SEARCH_PATHS}
+)
+
+IF(NOT SDL2_BUILDING_LIBRARY)
+	IF(NOT ${SDL2_INCLUDE_DIR} MATCHES ".framework")
+		# Non-OS X framework versions expect you to also dynamically link to
+		# SDL2main. This is mainly for Windows and OS X. Other (Unix) platforms
+		# seem to provide SDL2main for compatibility even though they don't
+		# necessarily need it.
+		FIND_LIBRARY(SDL2MAIN_LIBRARY
+			NAMES SDL2main
+			HINTS
+			$ENV{SDL2DIR}
+			PATH_SUFFIXES ${PATH_SUFFIXES}
+			PATHS ${SDL2_SEARCH_PATHS}
+		)
+	ENDIF(NOT ${SDL2_INCLUDE_DIR} MATCHES ".framework")
+ENDIF(NOT SDL2_BUILDING_LIBRARY)
+
+# SDL2 may require threads on your system.
+# The Apple build may not need an explicit flag because one of the
+# frameworks may already provide it.
+# But for non-OSX systems, I will use the CMake Threads package.
+IF(NOT APPLE)
+	FIND_PACKAGE(Threads)
+ENDIF(NOT APPLE)
+
+# MinGW needs an additional link flag, -mwindows
+# It's total link flags should look like -lmingw32 -lSDL2main -lSDL2 -mwindows
+IF(MINGW)
+	SET(MINGW32_LIBRARY mingw32 "-mwindows" CACHE STRING "mwindows for MinGW")
+ENDIF(MINGW)
+
+IF(SDL2_LIBRARY_TEMP)
+	# For SDL2main
+	IF(NOT SDL2_BUILDING_LIBRARY)
+		IF(SDL2MAIN_LIBRARY)
+			SET(SDL2_LIBRARY_TEMP ${SDL2MAIN_LIBRARY} ${SDL2_LIBRARY_TEMP})
+		ENDIF(SDL2MAIN_LIBRARY)
+	ENDIF(NOT SDL2_BUILDING_LIBRARY)
+
+	# For OS X, SDL2 uses Cocoa as a backend so it must link to Cocoa.
+	# CMake doesn't display the -framework Cocoa string in the UI even
+	# though it actually is there if I modify a pre-used variable.
+	# I think it has something to do with the CACHE STRING.
+	# So I use a temporary variable until the end so I can set the
+	# "real" variable in one-shot.
+	IF(APPLE)
+		SET(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} "-framework Cocoa")
+	ENDIF(APPLE)
+
+	# For threads, as mentioned Apple doesn't need this.
+	# In fact, there seems to be a problem if I used the Threads package
+	# and try using this line, so I'm just skipping it entirely for OS X.
+	IF(NOT APPLE)
+		SET(SDL2_LIBRARY_TEMP ${SDL2_LIBRARY_TEMP} ${CMAKE_THREAD_LIBS_INIT})
+	ENDIF(NOT APPLE)
+
+	# For MinGW library
+	IF(MINGW)
+		SET(SDL2_LIBRARY_TEMP ${MINGW32_LIBRARY} ${SDL2_LIBRARY_TEMP})
+	ENDIF(MINGW)
+
+	# Set the final string here so the GUI reflects the final state.
+	SET(SDL2_LIBRARY ${SDL2_LIBRARY_TEMP} CACHE STRING "Where the SDL2 Library can be found")
+	# Set the temp variable to INTERNAL so it is not seen in the CMake GUI
+	SET(SDL2_LIBRARY_TEMP "${SDL2_LIBRARY_TEMP}" CACHE INTERNAL "")
+ENDIF(SDL2_LIBRARY_TEMP)
+
+# message("</FindSDL2.cmake>")
+
+INCLUDE(FindPackageHandleStandardArgs)
+
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(SDL2 REQUIRED_VARS SDL2_LIBRARY SDL2_INCLUDE_DIR)
+
+MARK_AS_ADVANCED(SDL2MAIN_LIBRARY SDL2_LIBRARY SDL2_INCLUDE_DIR)

libs/wxWidgets-3.3.1/build/cmake/modules/FindWAYLANDEGL.cmake

@@ -0,0 +1,20 @@
+find_package(PkgConfig)
+pkg_check_modules(WAYLANDEGL QUIET wayland-egl)
+
+set(VERSION_OK TRUE)
+if (WAYLANDEGL_VERSION)
+    if (WAYLANDEGL_FIND_VERSION_EXACT)
+        if (NOT("${WAYLANDEGL_FIND_VERSION}" VERSION_EQUAL "${WAYLANDEGL_VERSION}"))
+            set(VERSION_OK FALSE)
+        endif ()
+    else ()
+        if ("${WAYLANDEGL_VERSION}" VERSION_LESS "${WAYLANDEGL_FIND_VERSION}")
+            set(VERSION_OK FALSE)
+        endif ()
+    endif ()
+endif ()
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(WAYLANDEGL DEFAULT_MSG WAYLANDEGL_LIBRARIES VERSION_OK)
+
+mark_as_advanced(WAYLANDEGL_LIBRARIES)

libs/wxWidgets-3.3.1/build/cmake/modules/FindWEBKIT.cmake

@@ -0,0 +1,40 @@
+# - Find Webkit
+# Find the Webkit includes and library
+#
+#  WEBKIT_INCLUDE_DIR - Where to find webkit include sub-directory.
+#  WEBKIT_LIBRARIES   - List of libraries when using Webkit.
+#  WEBKIT_FOUND       - True if Webkit found.
+
+SET(WEBKIT_VERSION 1.0)
+if(DEFINED WEBKIT_FIND_VERSION)
+    SET(WEBKIT_VERSION ${WEBKIT_FIND_VERSION})
+endif()
+
+SET(WEBKIT_INCLUDE_DIR WEBKIT_INCLUDE_DIR-NOTFOUND)
+SET(WEBKIT_LIBRARY WEBKIT_LIBRARY-NOTFOUND)
+SET(WEBKIT_LIBRARIES WEBKIT_LIBRARIES-NOTFOUND)
+
+FIND_PATH(WEBKIT_INCLUDE_DIR webkit/webkit.h
+    PATH_SUFFIXES "webkitgtk-${WEBKIT_VERSION}"
+)
+
+SET(WEBKIT_NAMES "webkitgtk-${WEBKIT_VERSION}")
+FIND_LIBRARY(WEBKIT_LIBRARY
+    NAMES ${WEBKIT_NAMES}
+)
+
+# Handle the QUIETLY and REQUIRED arguments and set WEBKIT_FOUND to
+# TRUE if all listed variables are TRUE.
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(
+    WEBKIT DEFAULT_MSG
+    WEBKIT_LIBRARY WEBKIT_INCLUDE_DIR
+)
+
+IF(WEBKIT_FOUND)
+    SET( WEBKIT_LIBRARIES ${WEBKIT_LIBRARY} )
+ELSE(WEBKIT_FOUND)
+    SET( WEBKIT_LIBRARIES )
+ENDIF(WEBKIT_FOUND)
+
+MARK_AS_ADVANCED(WEBKIT_LIBRARY WEBKIT_LIBRARIES WEBKIT_INCLUDE_DIR)

libs/wxWidgets-3.3.1/build/cmake/modules/FindWEBKIT2.cmake

@@ -0,0 +1,50 @@
+# - Find Webkit2
+# Find the Webkit2 includes and library
+#
+#  WEBKIT2_INCLUDE_DIR - Where to find Webkit2 include sub-directory.
+#  WEBKIT2_LIBRARIES   - List of libraries when using Webkit2.
+#  WEBKIT2_FOUND       - True if Webkit2 found.
+
+SET(WEBKIT2_VERSION 4.0)
+if(DEFINED WEBKIT2_FIND_VERSION)
+    SET(WEBKIT2_VERSION ${WEBKIT2_FIND_VERSION})
+endif()
+
+set(WEBKIT2_INCLUDE_DIR WEBKIT2_INCLUDE_DIR-NOTFOUND)
+set(WEBKIT2_LIBRARY WEBKIT2_LIBRARY-NOTFOUND)
+set(WEBKIT2_JS_LIBRARY WEBKIT2_JS_LIBRARY-NOTFOUND)
+set(WEBKIT2_LIBRARIES WEBKIT2_LIBRARIES-NOTFOUND)
+
+FIND_PATH(WEBKIT2_INCLUDE_DIR webkit2/webkit2.h
+    PATH_SUFFIXES "webkitgtk-${WEBKIT2_VERSION}"
+)
+
+SET(WEBKIT2_NAMES "webkit2gtk-${WEBKIT2_VERSION}")
+FIND_LIBRARY(WEBKIT2_LIBRARY
+    NAMES ${WEBKIT2_NAMES}
+)
+
+SET(WEBKIT2_JS_NAMES "javascriptcoregtk-${WEBKIT2_VERSION}")
+FIND_LIBRARY(WEBKIT2_JS_LIBRARY
+    NAMES ${WEBKIT2_JS_NAMES}
+)
+
+# Handle the QUIETLY and REQUIRED arguments and set WEBKIT2_FOUND to
+# TRUE if all listed variables are TRUE.
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(
+    WEBKIT2 DEFAULT_MSG
+    WEBKIT2_LIBRARY WEBKIT2_INCLUDE_DIR
+)
+
+IF(WEBKIT2_FOUND)
+    SET( WEBKIT2_LIBRARIES ${WEBKIT2_LIBRARY} ${WEBKIT2_JS_LIBRARY} )
+ELSE(WEBKIT2_FOUND)
+    SET( WEBKIT2_LIBRARIES )
+ENDIF(WEBKIT2_FOUND)
+
+MARK_AS_ADVANCED(WEBKIT2_LIBRARY
+                 WEBKIT2_LIBRARIES
+                 WEBKIT2_INCLUDE_DIR
+                 WEBKIT2_JS_LIBRARY
+)

libs/wxWidgets-3.3.1/build/cmake/modules/FindXKBCommon.cmake

@@ -0,0 +1,28 @@
+# FindXKBCommon
+
+find_package(PkgConfig)
+pkg_check_modules(PC_XKBCOMMON QUIET xkbcommon)
+
+find_path(XKBCOMMON_INCLUDE_DIRS
+    NAMES xkbcommon.h
+    HINTS ${PC_XKBCOMMON_INCLUDEDIR}
+          ${PC_XKBCOMMON_INCLUDE_DIRS}
+    PATH_SUFFIXES xkbcommon
+)
+
+find_library(XKBCOMMON_LIBRARIES
+    NAMES xkbcommon
+    HINTS ${PC_XKBCOMMON_LIBDIR}
+          ${PC_XKBCOMMON_LIBRARY_DIRS}
+)
+
+set(XKBCOMMON_VERSION ${PC_XKBCOMMON_VERSION})
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(XKBCommon REQUIRED_VARS XKBCOMMON_INCLUDE_DIRS XKBCOMMON_LIBRARIES
+                                            VERSION_VAR   XKBCOMMON_VERSION)
+
+mark_as_advanced(
+    XKBCOMMON_INCLUDE_DIRS
+    XKBCOMMON_LIBRARIES
+)

libs/wxWidgets-3.3.1/build/cmake/modules/FindXTEST.cmake

@@ -0,0 +1,51 @@
+# - Find XTEST
+# Find the XTEST libraries
+#
+#  This module defines the following variables:
+#     XTEST_FOUND        - true if XTEST_INCLUDE_DIR & XTEST_LIBRARY are found
+#     XTEST_LIBRARIES    - Set when XTEST_LIBRARY is found
+#     XTEST_INCLUDE_DIRS - Set when XTEST_INCLUDE_DIR is found
+#
+#     XTEST_INCLUDE_DIR  - where to find XTest.h, etc.
+#     XTEST_LIBRARY      - the XTEST library
+#
+
+#=============================================================================
+# Copyright 2011 O.S. Systems Software Ltda.
+# Copyright 2011 Otavio Salvador <otavio@ossystems.com.br>
+# Copyright 2011 Marc-Andre Moreau <marcandre.moreau@gmail.com>
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+#=============================================================================
+
+find_path(XTEST_INCLUDE_DIR NAMES X11/extensions/XTest.h
+          PATH_SUFFIXES X11/extensions
+          PATHS /opt/X11/include
+          DOC "The XTest include directory"
+)
+
+find_library(XTEST_LIBRARY NAMES Xtst
+          PATHS /opt/X11/lib
+          DOC "The XTest library"
+)
+
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(XTEST DEFAULT_MSG XTEST_LIBRARY XTEST_INCLUDE_DIR)
+
+if(XTEST_FOUND)
+  set( XTEST_LIBRARIES ${XTEST_LIBRARY} )
+  set( XTEST_INCLUDE_DIRS ${XTEST_INCLUDE_DIR} )
+endif()
+
+mark_as_advanced(XTEST_INCLUDE_DIR XTEST_LIBRARY)
+

libs/wxWidgets-3.3.1/build/cmake/modules/cotire_test/CMakeLists.txt

@@ -0,0 +1,21 @@
+# cotire example project
+
+cmake_minimum_required(VERSION 2.8.12)
+
+if (POLICY CMP0058)
+	# Ninja requires custom command byproducts to be explicit
+	cmake_policy(SET CMP0058 NEW)
+endif()
+
+project (CotireExample)
+
+set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/..")
+
+if (NOT CMAKE_VERSION VERSION_LESS "3.1.0")
+	set (CMAKE_CXX_STANDARD "98")
+	set (CMAKE_CXX_EXTENSIONS OFF)
+endif()
+
+include(cotire)
+
+add_subdirectory(src)

libs/wxWidgets-3.3.1/build/cmake/modules/cotire_test/license

@@ -0,0 +1,22 @@
+Copyright (c) 2012-2018 Sascha Kratky
+
+Permission is hereby granted, free of charge, to any person
+obtaining a copy of this software and associated documentation
+files (the "Software"), to deal in the Software without
+restriction, including without limitation the rights to use,
+copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the
+Software is furnished to do so, subject to the following
+conditions:
+
+The above copyright notice and this permission notice shall be
+included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
+OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
+HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
+WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
+FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
+OTHER DEALINGS IN THE SOFTWARE.

libs/wxWidgets-3.3.1/build/cmake/modules/cotire_test/src/CMakeLists.txt

@@ -0,0 +1,31 @@
+# cotire example project
+
+add_executable(example main.cpp example.cpp log.cpp log.h example.h)
+
+# enable warnings
+if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
+	set_target_properties(example PROPERTIES COMPILE_FLAGS "-Weverything")
+elseif (CMAKE_CXX_COMPILER_ID MATCHES "GNU")
+	set_target_properties(example PROPERTIES COMPILE_FLAGS "-Wall -Wextra")
+endif()
+
+cotire(example)
+
+# cotire sets the following properties
+get_target_property(_unitySource example COTIRE_CXX_UNITY_SOURCE)
+get_target_property(_prefixHeader example COTIRE_CXX_PREFIX_HEADER)
+get_target_property(_precompiledHeader example COTIRE_CXX_PRECOMPILED_HEADER)
+get_target_property(_unityTargetName example COTIRE_UNITY_TARGET_NAME)
+
+if (_unitySource)
+	message(STATUS "example unity source: ${_unitySource}")
+endif()
+if (_prefixHeader)
+	message(STATUS "example prefix header: ${_prefixHeader}")
+endif()
+if (_precompiledHeader)
+	message(STATUS "example precompiled header: ${_precompiledHeader}")
+endif()
+if (TARGET ${_unityTargetName})
+	message(STATUS "example unity target: ${_unityTargetName}")
+endif()

libs/wxWidgets-3.3.1/build/cmake/modules/cotire_test/src/example.cpp

@@ -0,0 +1,24 @@
+// cotire example project
+
+#include "example.h"
+
+#ifndef NDEBUG
+#include <algorithm>
+#include <iterator>
+#endif
+
+namespace example {
+
+std::string get_message() {
+	char msg_chrs[] = { 'C', 'o', 't', 'i', 'r', 'e', 'd', '!' };
+#ifdef NDEBUG
+	return std::string(&msg_chrs[0], &msg_chrs[sizeof(msg_chrs)]);
+#else
+	std::string msg;
+	msg.reserve(sizeof(msg_chrs));
+	std::copy(msg_chrs, msg_chrs + sizeof(msg_chrs), std::back_inserter(msg));
+	return msg;
+#endif
+}
+
+}

libs/wxWidgets-3.3.1/build/cmake/modules/cotire_test/src/example.h

@@ -0,0 +1,10 @@
+// cotire example project
+
+#include <string>
+
+namespace example {
+
+std::string get_message();
+
+}
+

libs/wxWidgets-3.3.1/build/cmake/modules/cotire_test/src/log.cpp

@@ -0,0 +1,17 @@
+// cotire example project
+
+#include "log.h"
+
+#include <iostream>
+
+namespace logging {
+
+void error(const std::string& msg) {
+	std::cerr << msg << std::endl;
+}
+
+void info(const std::string& msg) {
+	std::cout << msg << std::endl;
+}
+
+}

libs/wxWidgets-3.3.1/build/cmake/modules/cotire_test/src/log.h

@@ -0,0 +1,10 @@
+// cotire example project
+
+#include <string>
+
+namespace logging {
+
+void error(const std::string& msg);
+void info(const std::string& msg);
+
+}

libs/wxWidgets-3.3.1/build/cmake/modules/cotire_test/src/main.cpp

@@ -0,0 +1,12 @@
+// cotire example project main
+
+#include <string>
+
+#include "example.h"
+#include "log.h"
+
+int main()
+{
+	std::string msg = example::get_message();
+	logging::info(msg);
+}